**Annotated Output for Analyzing Repeated Measures Data**

**MSDS 6372**

**Code Used – Same data from asynchronous material**

**data** repeated;

input subject time1 time2 time3;

datalines;

1 30 28 34

2 14 18 22

3 24 20 30

4 38 34 44

5 26 28 30

;

**run**;

/\* proc print data=repeated; run; \*/

title 'Repeated Measures ANOVA';

**PROC** **GLM** data=repeated; /\*data option not necessary, but it's good practice \*/

model time1 time2 time3 = / nouni;

/\*nouni = no univariate tests. If not specified, SAS will run three \*/

/\* univariate ANOVA, one for each level of time \*/

repeated time **3** polynomial/ summary printe;

/\* repeated tells SAS that the variables on the left hand side of the model \*/

/\* statement are repeated measures and not separate variables \*/

/\* polynomial asks for contrasts of degrees 1 and 2 (linear and quadratic \*/

/\* summary asks for output for each contrast \*/

/\*printe asks for sphericity tests \*/

**run**;

**quit**; /\* Proc GLM is interactive. The quit statement stops it. \*/

**Edited and annotated output in List Format (because it’s easier to annotate than output in HTML format)**

Repeated Measures ANOVA

The GLM Procedure

Repeated Measures Level Information

Dependent Variable time1 time2 time3

Level of time 1 2 3

**The "Repeated Measures Level Information" table above gives information about the repeated measures effect. In this example, the within-subject effect is Time, which has the levels 1, 2, and 3. The way these levels are specified implies that time points are equally spaced. If time points are not equally spaced, it is best to specify the effect with unevenly spaced numbers. For example, if measurements were taken at 1 week, 3 weeks, and 12 weeks after a treatment, the repeated measures levels should be specified as 1, 3, and 12.**

Partial Correlation Coefficients from the Error SSCP Matrix / Prob > |r|

DF = 4 time1 time2 time3

time1 1.000000 0.927917 0.984189

0.0230 0.0024

time2 0.927917 1.000000 0.898020

0.0230 0.0385

time3 0.984189 0.898020 1.000000

0.0024 0.0385

**The section above gives the correlation matrix for the error terms. For the current example, the correlations in this matrix answer the following question, “To what extent do the scores at one time predict scores at another time? The two-tailed p-value is given below each correlation.**

**IMPORTANT: Most of these correlations should be significant. If they are not, then it is not necessary to use repeated measures. The abbreviation SSCP stands for sums of squares and cross products.**

**The section below gives the correlation matrix for the error term for the transformed variables by a polynomial contrast. Hence, “time\_1” denotes the linear effect of time and “time\_2”, the quadratic effect. If we had a fourth time, there would also be a “time\_3”, the cubic effect, etc. In other words, the polynomial contrasts displayed will have degrees up to the number of levels of the repeated measures factor – 1. This first table shows the variance-covariance matrix for the contrasts (variance on diagonals, covariance on off-diagonals) as estimated by SAS.**

E = Error SSCP Matrix

time\_N represents the nth degree polynomial contrast for time

time\_1 time\_2

time\_1 5.60000 -0.46188

time\_2 -0.46188 32.80000

**This next section shows the correlations between the linear and quadratic contrasts. Ideally, these correlations should not be statistically significant, because they are supposed to be orthogonal. But, really, unless you truly understand how these two tables (the one above and the one below) are calculated and know their practical value, you can ignore these.**

Partial Correlation Coefficients from the Error SSCP Matrix of the

Variables Defined by the Specified Transformation / Prob > |r|

DF = 4 time\_1 time\_2

time\_1 1.000000 -0.034080

0.9566

time\_2 -0.034080 1.000000

0.9566

Sphericity Tests

**The following are the tests of Sphericity. A large p-value indicates that the Sphericity assumption is NOT violated, which means that it is OK to use a univariate repeated measures approach. Of course, this leads to the somewhat illogical action of proceeding based on ACCEPTING a null hypothesis, which is something that statisticians are loath to do. Anyway, philosophical considerations aside, if the p-value is small, the sphericity assumption is violated, and we must either use the GG or HF adjustments to the degrees of freedom for the F statistic, or we need to use the multivariate approach.**

Mauchly's

Variables DF Criterion Chi-Square Pr > ChiSq

Transformed Variates 2 0.4976852 2.0933627 0.3511

Orthogonal Components 2 0.4976852 2.0933627 0.3511

**In this case, the p-value for Mauchly’s test of sphericity is large (Chi-square = 2.093, df = 2, p = 0.3511); therefore, we do not reject the null hypothesis. The assumption of sphericity of the variance-covariance matrix is NOT violated for these data. Note that we haven’t checked any other assumptions, like normality. Those assumption checks should be done, too, preferably just using descriptive statistics and graphics.**

**It turns out that SAS automatically does the multivariate repeated measures tests. I’m not sure why that SAS prints out the MANOVA results next instead of the univariate repeated measures results, as would seem the logical order. Go figure.**

MANOVA Test Criteria and Exact F Statistics for the Hypothesis of no time Effect

H = Type III SSCP Matrix for time

E = Error SSCP Matrix

S=1 M=0 N=0.5

Statistic Value F Value Num DF Den DF Pr > F

Wilks' Lambda 0.06013986 23.44 2 3 0.0147

Pillai's Trace 0.93986014 23.44 2 3 0.0147

Hotelling-Lawley Trace 15.62790698 23.44 2 3 0.0147

Roy's Greatest Root 15.62790698 23.44 2 3 0.0147

**Recall that the MANOVA approach involves creating multiple response variables from the repeated measures variables by subtracting the repeated measures vector across each subject from one another. However, it does not necessarily do the differencing method of subtracting the vectors at each repeated measure from one another. The user can specify how the response variables for the MANOVA are created by specifying a particular type of contrast in the repeated statement. The default contrast is one that tests one level of the repeated measures effect as a control. The other levels are compared to the control level. For example, the following statement (which is the one used in our code) tells SAS that “time” is a repeated measures factor with three levels (“time 3”), and to print the results of the Mauchly’s criterion (“printe” option).**

repeated time **3** / printe;

**No contrast statement is given; therefore, the multivariate ANOVA approach creates differences between the first time level (let’s call it t1) and the next two time levels (t1 – t2 and t1 – t3). Therefore, the multivariate tests above are for the situation where the response variables are the differences between times 2 and 3 and time 1. Suppose I specify the following:**

repeated time **3** contrast(2)/ summary printe;.

**This statement tells SAS to calculate the MANOVA tests using response variables which are created as differences between the SECOND level of time and the other two levels (i.e. time2 – time3 and time2 – time1). The “summary” option tells SAS to print univariate ANOVAs for each response variable so that the user can determine how the score at each non-control level value (time points, in this case) differs from the control level value.**

**Here, we did a polynomial contrast**

repeated time **3** polynomial / summary printe;.

**Which means that SAS will perform a test to see whether the data increase linearly or can be modeled by a quadratic. Why will it not test for a cubic polynomial? Here is the output**

time\_N represents the nth degree polynomial contrast for time

Contrast Variable: time\_1

Source DF Type III SS Mean Square F Value Pr > F

Mean 1 78.40000000 78.40000000 56.00 0.0017

Error 4 5.60000000 1.40000000

**These are the results for the linear polynomial (a straight line fit). We see that the p-value is small; therefore, we reject the null hypothesis that these data do not have a linear trend. There is evidence that there is a linear trend from time 1 to time 3.**

Contrast Variable: time\_2

Source DF Type III SS Mean Square F Value Pr > F

Mean 1 43.20000000 43.20000000 5.27 0.0834

Error 4 32.80000000 8.20000000

**These are the results for the quadratic contrast. We do not reject the null hypothesis that there is a quadratic relationship among the scores at each time. Therefore, a curve is not likely to explain the relationship among the times.**

**Other contrasts are possible. The options are listed below.**

**POLYNOMIAL: Useful when testing a trend for quantitative values of a treatment. The user can specify unequally spaced level values in parenthesis after the number of levels given in the REPEATED statement. If level values are not specified SAS assumes that the levels are equally spaced. Therefore, if I wanted to specify a polynomial contrast on the repeated measures variable, where measurements were taken at 1 week, 3 weeks, and 12 weeks after a treatment, I would type:**

repeated time **3** (1 3 12) polynomial / summary printe;.

**HELMERT: Compares a level of a repeated measure to the mean of subsequent levels. It is most useful when the user wants to know when a response no longer changes (maybe the response plateaus at a certain time point, for example).**

**MEAN: Specifies response variables for the MANOVA which are each level value tested against the combined mean of the other level values (i.e. time 1 vs. (time 2 + time 3)/2). If k is the number of levels of the repeated measures factor, the MEAN option specifies k – 1 contrasts of this type.**

**PROFILE: Used for pairwise tests of adjacent levels. For our example, specifying a profile contrast will create the response variables time 1 – time 2 and time 2 – time 3. It is useful for determining the level at which a response changes.**

Repeated Measures Analysis of Variance

Univariate Tests of Hypotheses for Within Subject Effects

Adj Pr > F

Source DF Type III SS Mean Square F Value Pr > F G - G H - F

time 2 121.6000000 60.8000000 12.67 0.0033 0.0122 0.0054

Error(time) 8 38.4000000 4.8000000

**This last table gives the results for the univariate repeated measures ANOVA. The p-value for the time main effect is highlighted in yellow (p = 0.0033, F = 12.67, df = 2, 8). GG and HF adjusted p-values are highlighted in green and pink, respectively. The F value for these adjustments is still 12.67, but the degrees of freedom will be different; they will be adjusted according to the formulas given in the asynchronous material with the following epsilon values:**

Greenhouse-Geisser Epsilon 0.6656

Huynh-Feldt Epsilon 0.8724

**Both of these epsilon values are large, indicating that not much of an adjustment is needed (recall the epsilon = 1 means perfect sphericity). The GG epsilon is less than the rather arbitrary level of 0.7 that is suggested for using Tukey vs. Bonferroni multiple comparison adjustments. Bonferroni controls the Type I error better than Tukey when sphericity is violated, but Tukey is more powerful. And there are other types of multiple comparison adjustments that aren’t mentioned here and whose Type I/Type II error properties in the presence of violations of sphericity are unknown to this professor (extra credit – create a PPT deck of no more than 5 slides describing a multiple comparison adjustment that performs well – in terms of Type I or Type II error or both – in the presence of violations of sphericity). At the present moment, my advice is to use Tukey unless sphericity is violated AND you want to control Type I error rather than power.**